notes-shao2003

Unnamed repository; edit this file 'description' to name the repository.
git clone git://pcardenasb.com/notes-shao2003.git
Log | Files | Refs

anki.pl (2640B)


      1 #!/usr/bin/env perl
      2 use strict;
      3 use warnings;
      4 
      5 my $deck_name = "shao2003";
      6 
      7 print "#separator:Comma\n";
      8 print "#html:true\n";
      9 print "#deck:notes::$deck_name\n";
     10 print "#notetype:Basic\n";
     11 print "#columns:Front,Back,Tags\n";
     12 
     13 sub quote_csv {
     14     my $s = shift;
     15     $s =~ s/"/""/g;
     16     return qq{"$s"};
     17 }
     18 
     19 sub escape_html {
     20     my $s = shift;
     21     $s =~ s/&/&/g;
     22     $s =~ s/</&lt;/g;
     23     $s =~ s/>/&gt;/g;
     24     return $s;
     25 }
     26 
     27 sub latex_to_html_fast {
     28     my $s = shift;
     29     $s =~ s/^\t+//mg;
     30 
     31     $s = escape_html($s);
     32     $s =~ s{\\emph\{([^{}]*)\}}{<em>$1</em>}g;
     33 
     34     $s =~ s{
     35         \\begin\{(align\*?|equation\*?|gather\*?)\}
     36         (.*?)
     37         \\end\{\1\}
     38     }{\\[\\begin{$1}$2\\end{$1}\\]}gxs;
     39 
     40     1 while $s =~ s{
     41         \\begin\{itemize\}
     42         ((?:(?!\\begin\{itemize\}|\\end\{itemize\}).)*)
     43         \\end\{itemize\}
     44     }{
     45         my @items = grep { /\S/ } split /\\item\b/, $1;
     46         "<ul>" . join("", map {
     47             my $x = $_;
     48             $x =~ s/^\s+|\s+$//g;
     49             $x =~ s/\n\s*\n/\n/g;
     50             "<li>$x</li>"
     51         } @items) . "</ul>";
     52     }egxs;
     53 
     54     my @blocks = grep { /\S/ } split /\n\s*\n/, $s;
     55     return join "\n", map {
     56         /^<ul>/ ? $_ : "<p>$_</p>"
     57     } @blocks;
     58 }
     59 
     60 
     61 
     62 my $style = "
     63 <style>
     64 .card {
     65     font-family: serif;
     66     text-align: left;
     67     margin-inline: auto;
     68     max-width: 36em;
     69 }
     70 </style>
     71 ";
     72 
     73 for my $file (glob("tex/chapter_*.tex")) {
     74     (my $lecture_num = $file) =~ s{^.*/chapter_(\d\d)\.tex$}{$1};
     75 
     76     open my $fh, "<", $file or die $!;
     77     my ($lecture_title) = (<$fh> =~ /\\title\s+(.*)/);
     78     my $tex = do { local $/; <$fh> };
     79 
     80     my @lecture_block_titles;
     81     while (
     82         $tex =~ /
     83             ^\\begin\{(?<env>[^}]*)\}
     84             \{(?<id>.*?)\}\{(?<name>.*?)\}\R
     85             (?<body>.*?)
     86             ^\\end\{\k<env>\}
     87         /smgx
     88     ) {
     89         my $env  = $+{env};
     90         my $id   = $+{id};
     91         my $name = $+{name};
     92         my $body = $+{body};
     93 
     94         my $title = sprintf("%s %s: %s", $id, $env, $name);
     95         push @lecture_block_titles, $title;
     96 
     97         my $back = latex_to_html_fast($body);
     98         my $front = $style . $title;
     99         my $tags = "${deck_name}::lecture::$lecture_num ${deck_name}::env::$env";
    100 
    101         print quote_csv($front), ",", quote_csv("\n" . $back), ",", quote_csv($tags), "\n";
    102     }
    103 
    104     my $front = $style . "$lecture_num.99 Index";
    105     my $back = "<strong>$lecture_title</strong>\n" . join("\n", map { "<div>$_</div>" } @lecture_block_titles);
    106     my $tags = "${deck_name}::lecture::$lecture_num ${deck_name}::env::index";
    107     print quote_csv($front), ",", quote_csv("\n" . $back), ",", quote_csv($tags), "\n";
    108 }